;===========================================================================
; 文件名:	Sys_init.asm
;
; 模塊名: S Y S _ I N I T				      
;
; 公司:	達盛科技
;
; 描述:  初始化 F24x/xx 器件
;=====================================================================================
; 修改紀錄:
;-------------------------------------------------------------------------------------
; 最后更改時間：2005.08.22	版本號：Ver 1.0	
;===========================================================================
		.include	x24x_app.h
		.def	SYS_INIT
		.ref	GPR0

stack_size	.set	20h
stack_start	.usect	"stack",stack_size	

SYS_INIT:
		POINT_PG0
		SETC	INTM			;禁止中斷
		SPLK	#0h, IMR		;屏蔽所有中斷
		SPLK	#0FFh, IFR		;清除所用中斷標志

;初始化 PDP 中斷標志		
		LDP	#PIRQR0>>7
		LACC	PIRQR0		; 清除未決的 PDP 中斷標志
		AND	#0FFFEh
		SACL	PIRQR0
		LACC	PIRQR2		; 清除未決的 PDP 中斷標志
		AND	#0FFFEh
		SACL	PIRQR2
		POINT_EV
		LACC	EVAIFRA		; 清除 PDPINTA 中斷標志
		OR	#0001h
		SACL	EVAIFRA 
		LDP	#EVBIFRA>>7
		LACC	EVBIFRA		; 清除 PDPINTB 中斷標志
		OR	#0001h
		SACL	EVBIFRA 
		
		POINT_PG0
		CLRC	SXM				;禁止符號擴展
		CLRC	OVM				;禁止溢出保護
		CLRC	CNF				;塊B0設置為數據存儲器.
		SPM	0
		LAR	AR1, #stack_start	;初始化軟件堆棧指針
		MAR	*,AR1

		POINT_B0
		SPLK	#00C0h, GPR0	;設置'1' I/O 空間等待狀態 
		OUT	GPR0, WSGR

		POINT_PF1 
   
		.if (x4_PLL)  
    		SPLK	#0085h, SCSR1	; x4 PLL, ADC 使能, EV1使能, 清除無效地址標志         
		.endif 
 
    		.if (x2_PLL)  
    		SPLK	#0285h, SCSR1	; x2 PLL, ADC 使能, EV1使能, 清除無效地址標志
		.endif 
   		SPLK	#004Fh, SCSR2		; I/P Oual set 11 clock cycle

;Comment out if WD is to be active
		SPLK	#006Fh, WD_CNTL 	;禁止 WD，當 VCCP=5V
		KICK_DOG
		RET
;----------------------------------------------------------------------